Online File

How to use this page

---

Rick Aster: Professional SAS Programming Shortcuts: Contents

Chapter 68
Online program
Storage management report

---

proc sql;
create table work.datasize as select
    trim(libname) || '.' || memname
       as dataset label='SAS Dataset Name' length=20,
    libname as libref label='Libref',
    memname as member label='Member',
    nvar label='N Vars', nobs label='N Obs',
    obslen label='Obs Len',
    nobs*obslen/1048576 as mbdata label='MB Data' format=s7.3,
    compress label='Compress',
    pcompress label='Comp%' format=f5.,
    (1 - pcompress/100)*(calculated mbdata)
       as mbcomp label='MB Comp' format=s7.3
    from dictionary.tables;
quit;
proc report data=work.datasize (where=(libref='MAIN'))
    nowd headskip colwidth=7;
   column dataset nvar nobs mbdata mbcomp compress save percent;
   define nvar / display spacing=0;
   define nobs / display spacing=1;
   define dataset / order spacing=0;
   define save / '  Saved' computed spacing=0 format=s7.3;
   define percent / '   %' computed spacing=0 format=f4.;
   rbreak after / ol summarize;
   compute save;
      save = mbdata.sum - mbcomp.sum;
      endcomp;
   compute percent;
      if mbdata.sum then percent = save/mbdata.sum*100;
      endcomp;
run;