Online File

How to use this page

---

Rick Aster: Professional SAS Programming Shortcuts: Contents

Chapter 18
Program
WDN and MX formats and informats

---

data work.wdn;
   retain type1 'I' type2 'N' fmtname 'WDN' hlo 'UJ';
   do weekday = 1 to 7;
      name = upcase(left(put('01jan2005'd + weekday, downame9.)));
      output;
      end;
run;
proc format cntlin=work.wdn (keep=type1 fmtname name weekday
    rename=(type1=type name=start weekday=label));
run;
proc format cntlin=work.wdn (keep=type2 fmtname name weekday hlo
    rename=(type2=type weekday=start name=label));
run;


data work.mxformat;
   retain type 'N' fmtname 'MX';
   do month = 1 to 12;
      name = upcase(left(put(mdy(month, 1, 1960), monname9.)));
      output;
      end;
run;
proc format cntlin=work.mxformat
    (rename=(month=start name=label));
run;
data work.mxinfmt;
   retain type 'I' fmtname 'MX' hlo 'UJ';
   do month = 1 to 12;
      name = upcase(left(put(mdy(month, 1, 1960), monname9.)));
      output;
      if length(name) > 3 then do; 
         name = substr(name, 1, 3);
         output;
         end;
      end;
run;
proc format cntlin=work.mxinfmt
    (rename=(name=start month=label));
run;